% V20210224 - 4.5.3 GW_ADD_LISTENER

INCLUDE "GW.bas"

% Create a page.
p = GW_NEW_PAGE()

% Prepare title bar string.
Title$ = GW_ADD_BAR_TITLE$("Listeners Example")

% Prepare two bar menus.
ARRAY.LOAD ar$[], "#File", "New", "Open", "Save"
Lmenu$ = GW_ADD_BAR_LMENU$(ar$[])

ARRAY.LOAD br$[], "#Options", "Settings", "Help", "About", "Exit"
Rmenu$ = GW_ADD_BAR_RMENU$(br$[])

% Add a title bar + 2 bar menu listeners.
titlebar = GW_ADD_TITLEBAR(p, Lmenu$ + Title$ + Rmenu$)
GW_ADD_LISTENER(p, titlebar, "lmenuchange", "Event: left bar menu changed!")
GW_ADD_LISTENER(p, titlebar, "rmenuchange", "Event: right bar menu changed!")
GW_ADD_TEXT(p, "The titlebar above has listeners on the events \"lmenuchange\" and \"rmenuchange\".")

% Add a panel + its listener.
panel = GW_ADD_PANEL(p, "<h1>I'm a panel</h1>\n<p>I have a listener on the \"close\" event. Tap outside of me.</p>")
GW_ADD_LISTENER(p, panel, "close", "Event: panel closed!")

% Add a link to open the panel.
GW_ADD_LINK(p, "Open the panel.", GW_SHOW_PANEL$(panel))

% Add an inputline + its 2 listeners.
inpuline = GW_ADD_INPUTLINE(p, "I'm an input line. I have a listener on 2 events: \"keydown\" (user typing) and \"clear\".", "Type something, or use the X button ->")
GW_ADD_LISTENER(p, inpuline, "keydown", "Event: key down in input line!")
GW_ADD_LISTENER(p, inpuline, "clear", "Event: input line cleared!")

% Add a checkbox + its listener.
checkbox = GW_ADD_CHECKBOX(p, ">I'm a checkbox, I have a listener on \"change\".")
GW_ADD_LISTENER(p, checkbox, "change", "Event: checkbox changed!")

% Add a flip switch + its listener.
flipswitch = GW_ADD_FLIPSWITCH(p, "I'm a flip switch with a listener on \"change\".", "Off", ">On")
GW_ADD_LISTENER(p, flipswitch, "change", "Event: flip switch changed!")

% Add 2 buttons + their listeners.
button1 = GW_ADD_BUTTON(p, "I'm a button with a listener on \"swipeleft\".", "")
GW_ADD_LISTENER(p, button1, "swipeleft", "Event: swipe left on button #1!")
button2 = GW_ADD_BUTTON(p, "I'm a button with a listener on \"swiperight\".", "")
GW_ADD_LISTENER(p, button2, "swiperight", "Event: swipe right on button #2!")

% Add an image + a listener.
GW_ADD_TEXT(p, "Below is an image with a listener on \"longpress\".")
image = GW_ADD_IMAGE(p, "cartman.png")
GW_ADD_LISTENER(p, image, "longpress", "Event: long press on image!")

% Add listener on whole page.
GW_ADD_TEXT(p, "This whole page has a listener on \"swipeleft\".")
GW_ADD_LISTENER(p, 0, "swipeleft", "Event: swipe left in page!")

% Now show the page.
GW_RENDER(p)

DO   % Wait for user action.
 r$ = GW_WAIT_ACTION$()

 % Place here any necessary code to process user actions.

 POPUP r$  % Some feedback.

% End when BACK key is pressed.
UNTIL r$ = "BACK"
END "End of Listeners example."